#Packager: Dimitris Tzemos <dijemos@gmail.com>

pkgname=alsa-lib
pkgver=1.2.5
pkgrel=1dj
source=("https://www.alsa-project.org/files/pub/lib/${pkgname}-${pkgver}.tar.bz2"
        "https://github.com/alsa-project/alsa-lib/commit/ddfc32abf5697de1618b9e7ffdf57a0f97013090.patch"
        "https://github.com/alsa-project/alsa-lib/commit/0e4ba2ea8c0402f12a645032a14693eb9b1278e6.patch"
        "https://github.com/alsa-project/alsa-lib/commit/9621d0bff2e60b43e329ffa5059ab19f2914ec14.patch")
docs=("Copying")
url="https://www.alsa-project.org"

slackdesc=\
(
#|-----handy-ruler------------------------------------------------------|
"alsa-lib (Advanced Linux Sound Architecture library)"
"The Advanced Linux Sound Architecture (ALSA) provides audio and MIDI"
"functionality to the Linux operating system. This is the ALSA library"
"(libasound) which is used by audio applications."
"For more information, see http://alsa-project.org"
)


build() {
  cd $startdir/src/$pkgname-$pkgver
  # fix loading of multiple cards
  # https://github.com/alsa-project/alsa-lib/issues/143
  patch -Np1 -i ../"ddfc32abf5697de1618b9e7ffdf57a0f97013090.patch" || return 1
  # probably fix issues with pipewire:
  # https://github.com/alsa-project/alsa-lib/issues/142
  patch -Np1 -i ../"0e4ba2ea8c0402f12a645032a14693eb9b1278e6.patch" || return 1
  patch -Np1 -i ../"9621d0bff2e60b43e329ffa5059ab19f2914ec14.patch" || return 1
  autoreconf -vfi
  ./configure --prefix=/usr \
		--libdir=/usr/lib${LIBDIRSUFFIX} \
		--localstatedir=/var \
		--sysconfdir=/etc \
		--build=$arch-slackware-linux
  make DESTDIR="$PKG" install || return 1
  make DESTDIR="$PKG" install -C doc || return 1
  install -vDm 644 {MEMORY-LEAK,TODO,NOTES,ChangeLog,doc/asoundrc.txt} \
    -t "${PKG}/usr/share/doc/${pkgname}"
  
}